;---------------------------------------------------------------------------
[statedef -2]
;---------------------------------------------------------------------------
;          ↓↓↓ここからコンフィグ設定↓↓↓
;---------------------------------------------------------------------------
[state config]
type=varset
triggerall=!ishelper
trigger1=(roundstate=0)||(roundstate=1)
trigger1=1||var(17):=0         ;broste値の初期値。ちなみにbrosteとはスマブラテイストの略。0から1000までの値で設定。
sysfvar(2)=0                   ;CSASの初期値。ちなみにCSASとは超すごいアーマーシステムの略。この数値が大きいほど耐性が強化される。0から10000までの値で設定。
ignorehitpause=1

[state config2]
type=varset
triggerall=!ishelper
trigger1=(roundstate=0)||(roundstate=1)
sysvar(3)=110000               ;初期ライフ。多すぎるように見えるが、防御値が通常のキャラの百分の一なので実質体力は1100。0から110000の間で設定。
ignorehitpause=1

[state config3]
type=null
triggerall=!ishelper
trigger1=1||var(31):=50        ;broste値の上昇量。0から100までの値で設定。
trigger1=1||var(32):=100       ;CSASの増加量。特定の状況で攻撃を食らった時に増える基準値。この値がそのまま増えるわけではないので要注意。0から1000までの値で設定。
trigger1=1||var(33):=100       ;CSASの削り量。特定の状況で攻撃を食らった時に削れる基準値。この値がそのまま削れるわけではないので要注意。0から1000までの値で設定。
trigger1=1||var(34):=1         ;CSASの時間減少値。常にこの値だけ減り続ける実数値。CSASが9000を超えると、この値が0でなくても自動減少は止まる。-1から100までの値で設定。
trigger1=1||var(35):=0         ;ステートを奪われている間にCSASを増やすかどうか。1の時に増やす。
trigger1=1||var(36):=900       ;ダメキャンの基準値。900だと、ライフの9割以上の威力の攻撃を無効化する。0から1000までの値で設定。1000に設定されるとダメキャン自体がOFFとなる。0に設定すると論外化。
trigger1=1||var(37):=0         ;CSASの下限値。CSASはこの値を下回ることはない。0から10000までの値で設定。
trigger1=1||var(14):=1000      ;CSASの上限値。CSASはこの値を上回ることはない。0から10000までの値で設定。
trigger1=1||var(2):=0          ;ゲジマユスイッチ。0でOFF。0以外でON。
trigger1=1||var(27):=0         ;カラー差有効化スイッチ。0でOFF。O以外でON。
trigger1=1||var(26):=1         ;ペナルティ強化スイッチ。0でOFF。O以外でON。
trigger1=1||var(59):=10        ;AIスイッチ。0でOFF。1から10でON。数値がそのままAIレベルになる。それ以外の数値を設定した場合は10になる。
ignorehitpause=1
;
;
;
;
;---------------------------------------------------------------------------
;          ↑↑↑ここまでコンフィグ設定↑↑↑
;---------------------------------------------------------------------------



;---------------------------------------------------------------------------
;          helper生成等
;---------------------------------------------------------------------------

[state too_many_explod_remove]
type=removeexplod
triggerall=!ishelper
trigger1=numexplod>200
ignorehitpause=1

[state hit_helper]
type=helper
triggerall=!ishelper
triggerall=roundstate=2
trigger1=numhelper(21030)=0
trigger1=numexplod(21030)=0
trigger1=enemynear,movecontact=0
stateno=21030
name="hithelper"
ID=21030
pos=0,0
postype=P1
helpertype=player
ownpal=0
keyctrl=0
size.shadowoffset=21030
supermovetime=2147483647
pausemovetime=2147483647
ignorehitpause=1

[state hit_explod_remove]
type=removeexplod
triggerall=!ishelper
trigger1=helper(21030),gethitvar(damage)!=0
ID=21030
ignorehitpause=1

[state hit_explod]
type=explod
triggerall=!ishelper
trigger1=helper(21030),gethitvar(damage)!=0
anim=21010
ID=21030
postype=p1
pos=0,0
bindtime=-1
removetime=ifelse(sysfvar(2)>=9000,180,abs(sysfvar(2)/50))+1
supermovetime = 99999
pausemovetime = 99999
ignorehitpause=1

[state checker_helper]
type=helper
triggerall=!ishelper
triggerall=roundstate=2
triggerall=numhelper(21040)=0
trigger1=numhelper(21040)=0
stateno=21040
name="checkerhelper"
ID=21040
pos=0,0
postype=P1
helpertype=player
ownpal=1
keyctrl=0
size.shadowoffset=21040
supermovetime=2147483647
pausemovetime=2147483647
ignorehitpause=1

[state HIDAN_helper]
type=helper
triggerall=!ishelper
triggerall=numhelper(21060)=0
trigger1=numexplod(4771893)!=0
trigger2=numexplod(4771894)!=0
trigger3=numexplod(4771895)!=0
trigger4=numexplod(4771896)!=0
trigger5=numexplod(4771899)!=0
stateno=21060
name="HIDAN_helper"
ID=21060
pos=0,0
postype=P1
helpertype=player
ownpal=1
keyctrl=0
size.shadowoffset=21060
size.height=0
size.head.pos=0,0
supermovetime=2147483647
pausemovetime=2147483647
ignorehitpause=1

[state life_start_set]
type=varset
triggerall=!ishelper
trigger1=(roundstate=0)||(roundstate=1)
trigger1=1||var(31):=0
sysvar(4)=110000-sysvar(3)
ignorehitpause=1

[state self_checker]
type=varset
triggerall=!ishelper
trigger1=1
sysfvar(1)=(((gametime*const(data.life)/114514)*(gametime*0.93))/1.919810931)/gametime*id
ignorehitpause=1

[state self_checker_helper]
type=varset
triggerall=ishelper
trigger1=1
sysfvar(1)=root,sysfvar(1)
ignorehitpause=1

;---------------------------------------------------------------------------

[state config_fix]
type=varset
triggerall=!ishelper
trigger1=(var(31)<0)||(var(31)>100)
trigger1=1||var(31):=100
trigger1=0
trigger2=(var(32)<0)||(var(32)>1000)
trigger2=1||var(32):=1000
trigger2=0
trigger3=(var(33)<0)||(var(33)>1000)
trigger3=1||var(33):=0
trigger3=0
trigger4=(var(34)<-1)||(var(34)>100)
trigger4=1||var(34):=0
trigger4=0
trigger5=(var(36)<0)||(var(36)>1000)
trigger5=1||var(36):=0
trigger5=0
trigger6=(var(37)<0)||(var(37)>10000)
trigger6=1||var(37):=10000
trigger6=0
trigger7=(var(14)<0)||(var(14)>10000)
trigger7=1||var(14):=10000
trigger7=0
trigger8=(var(59)<0)||(var(59)>10)
trigger8=1||var(59):=10
trigger8=0
trigger9=(var(27)!=0)&&(palno=[10,11])
trigger9=sysfvar(2)>(3000+ifelse(palno=10,2000,0))
trigger9=1||var(36):=0
trigger9=0
trigger10=(roundstate=0)||(roundstate=1)
sysvar(4)=110000-sysvar(3)
ignorehitpause=1

[state penalty_explod]
type=explod
triggerall=!ishelper
triggerall=numexplod(8101082)=0
trigger1=(var(26)!=0)
trigger1=(roundstate=0)||(roundstate=1)
trigger1=numenemy=[1,2]
trigger1=(enemy(0),movetype=A)||(enemy(0),movetype=H)
trigger2=(var(26)!=0)
trigger2=(roundstate=0)||(roundstate=1)
trigger2=numenemy=2
trigger2=(enemy(1),movetype=A)||(enemy(1),movetype=H)
trigger3=(var(26)!=0)
trigger3=var(36)<1000
trigger3=helper(21030),gethitvar(damage)>1100000
trigger4=sysfvar(2)>=var(14)
trigger5=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger5=numenemy=[1,2]
trigger5=enemy(0),numproj>50
trigger6=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger6=numenemy=2
trigger6=enemy(1),numproj>50
trigger7=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger7=numenemy=[1,2]
trigger7=enemy(0),numhelper>sysfvar(0)/2
trigger7=roundstate>=2
trigger8=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger8=numenemy=2
trigger8=enemy(1),numhelper>sysfvar(0)/2
trigger8=roundstate>=2
trigger9=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger9=numenemy=[1,2]
trigger9=enemy(0),numexplod>100
trigger10=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger10=numenemy=2
trigger10=enemy(1),numexplod>100
trigger11=numenemy=[1,2]
trigger11=enemy(0),gethitvar(damage)>enemy(0),life
trigger11=enemy(0),life=0
trigger11=enemy(0),alive!=0
trigger12=numenemy=2
trigger12=enemy(1),gethitvar(damage)>enemy(1),life
trigger12=enemy(1),life=0
trigger12=enemy(1),alive!=0
anim=21010
ID=8101082
postype=p1
pos=0,0
bindtime=-1
removetime=-1
supermovetime = 9999999
pausemovetime = 9999999
ignorehitpause=1

[state penalty_explod02]
type=explod
triggerall=!ishelper
triggerall=numexplod(8101081)=0
trigger1=alive=0
trigger1=sysvar(3)>0
trigger1=sysvar(4)<110000
trigger2=(110000-sysvar(4))!=sysvar(3)
trigger3=roundstate>=2
trigger3=numhelper(21070)=0
trigger4=(enemy(0),alive!=[0,1])||((numenemy>1)&&(enemy(1),alive!=[0,1]))
trigger5=(var(26)!=0)&&(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger5=numenemy=[1,2]
trigger5=roundstate<2
trigger5=numpartner=0
trigger5=enemy(0),life=0
trigger5=enemy(0),alive!=0
trigger6=(var(26)!=0)&&(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger6=roundstate<2
trigger6=numpartner=0
trigger6=numenemy=2
trigger6=enemy(1),life=0
trigger6=enemy(1),alive!=0
trigger7=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger7=roundstate<=2
trigger7=numenemy=1
trigger7=enemy(0),alive=0
trigger7=!win
trigger8=(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger8=roundstate<=2
trigger8=numenemy=2
trigger8=enemy(0),alive=0
trigger8=enemy(1),alive=0
trigger8=!win
trigger9=roundstate>=2
trigger9=numhelper(21072)=0
trigger10=(var(26)!=0)&&(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger10=numenemy=[1,2]
trigger10=enemy(0),stateno=5150
trigger10=enemy(0),life=0
trigger10=enemy(0),alive!=0
trigger11=(var(26)!=0)&&(((var(27)!=0)&&(palno!=[3,5]))||(var(27)=0))
trigger11=numenemy=2
trigger11=enemy(1),stateno=5150
trigger11=enemy(1),life=0
trigger11=enemy(1),alive!=0
trigger12=(var(26)!=0)
trigger12=numexplod(8101082)!=0
trigger12=anim=3304
trigger12=animtime>-10
trigger12=(!win)||((numenemy=1)&&(enemy(0),alive!=0))||((numenemy=2)&&(enemy(0),alive!=0)&&(enemy(1),alive!=0))
trigger13=(var(26)!=0)
trigger13=sysfvar(2)>=10000
anim=21010
ID=8101081
postype=p1
pos=0,0
bindtime=-1
removetime=-1
supermovetime = 9999999
pausemovetime = 9999999
ignorehitpause=1

[state config_checker]
type=null
triggerall=!ishelper
trigger1=(numexplod(8101082)!=0)||(numexplod(8101081)!=0)
trigger1=1||var(31):=100
trigger1=1||var(32):=1000
trigger1=1||var(33):=0
trigger1=1||var(34):=0
trigger1=1||var(35):=1
trigger1=1||var(37):=var(14)
trigger1=0
trigger2=numexplod(8101081)!=0
trigger2=1||var(37):=10000
trigger2=1||var(14):=10000
trigger2=0
trigger3=(enemy(0),alive!=[0,1])||((numenemy>1)&&(enemy(1),alive!=[0,1]))
trigger3=1||var(36):=0
trigger3=0
ignorehitpause=1


;---------------------------------------------------------------------------

[state level_explod]
type=explod
triggerall=!ishelper
trigger1=numexplod(4949794)=0
trigger1=sysfvar(2)>=300
trigger2=numexplod(4949794)<=1
trigger2=sysfvar(2)>=500
trigger3=numexplod(4949794)<=2
trigger3=sysfvar(2)>=1000
trigger4=numexplod(4949794)<=3
trigger4=sysfvar(2)>=3000
trigger5=numexplod(4949794)<=4
trigger5=sysfvar(2)>=5000
trigger6=numexplod(4949794)<=5
trigger6=sysfvar(2)>=9000
anim=21010
ID=4949794
postype=p1
pos=0,0
bindtime=-1
removetime=-1
supermovetime = 99999
pausemovetime = 99999
ignorehitpause=1

[state level_explodremove]
type=removeexplod
triggerall=!ishelper
trigger1=sysfvar(2)=0
trigger1=numexplod(4949794)>0
trigger2=sysfvar(2)<300
trigger2=numexplod(4949794)>0
trigger3=sysfvar(2)<500
trigger3=numexplod(4949794)>1
trigger4=sysfvar(2)<1000
trigger4=numexplod(4949794)>2
trigger5=sysfvar(2)<3000
trigger5=numexplod(4949794)>3
trigger6=sysfvar(2)<5000
trigger6=numexplod(4949794)>4
trigger7=sysfvar(2)<9000
trigger7=numexplod(4949794)>5
ID=4949794
supermovetime = 99999
pausemovetime = 99999
ignorehitpause=1

;---------------------------------------------------------------------------

[state commandvar_reset]
type=null
triggerall=!ishelper
trigger1=1||var(47):=0
trigger1=1||var(3):=0
ignorehitpause=1

[state oath_set]
type=varset
triggerall=!ishelper
trigger1=1
V=18
Value=ceil((440-(Life/250))/ifelse((var(27)!=0)&&(palno=4)&&(numexplod(8101082)=0),10,1))
ignorehitpause=1

[state oath_header]
type=varset
triggerall=!ishelper
trigger1=var(18)>440
trigger2=sysfvar(2)>=2000
trigger3=(var(27)!=0)&&(palno=10)&&(numexplod(8101082)=0)
trigger4=(var(27)!=0)&&(palno=12)&&(numexplod(8101082)=0)
trigger5=(numexplod(8101082)!=0)
V=18
Value=440
ignorehitpause=1

[state oath_footer]
type=varset
triggerall=!ishelper
trigger1=var(18)<0
trigger2=(var(27)!=0)&&(palno=[2,3])&&(numexplod(8101082)=0)
V=18
Value=0
ignorehitpause=1

[state broste_header]
type=varset
triggerall=!ishelper
trigger1=var(17)>1000
trigger2=sysfvar(2)>=3000
trigger3=(var(27)!=0)&&(palno=12)&&(numexplod(8101082)=0)
trigger4=(var(27)!=0)&&(palno=11)&&(numexplod(8101082)=0)
trigger5=(numexplod(8101082)!=0)
V=17
Value=1000
ignorehitpause=1

[state broste_footer]
type=varset
triggerall=!ishelper
trigger1=var(17)<0
trigger2=(var(27)!=0)&&(palno=[2,3])&&(numexplod(8101082)=0)
var(17)=0
ignorehitpause=1

[state CSAS_frame_decrease]
type=varset
triggerall=!ishelper
triggerall=roundstate=2
triggerall=((var(27)=0)||((var(27)!=0)&&(palno!=[9,12])))&&(numexplod(8101082)=0)
trigger1=(sysfvar(2)>=5000)&&(sysfvar(2)<9000)
trigger1=1||var(34):=var(34)*10
trigger2=(sysfvar(2)>=3000)&&(sysfvar(2)<5000)
trigger2=1||var(34):=var(34)*4
trigger3=(sysfvar(2)>=1000)&&(sysfvar(2)<3000)
trigger3=1||var(34):=var(34)*2
trigger4=(sysfvar(2)>=500)&&(sysfvar(2)<1000)
trigger5=(sysfvar(2)>=300)&&(sysfvar(2)<500)
trigger5=gametime%3=1
trigger6=(sysfvar(2)>=100)&&(sysfvar(2)<300)
trigger6=gametime%6=1
trigger7=(sysfvar(2)<100)
trigger7=gametime%12=1
sysfvar(2)=sysfvar(2)-var(34)
ignorehitpause=1

[state CSAS_enemies_decrease]
type=varset
triggerall=!ishelper
triggerall=numhelper(21030)=1
triggerall=helper(21030),gethitvar(damage)>0
triggerall=abs(helper(21030),gethitvar(damage))<(var(36)*110)
triggerall=numhelper(21040)!=0
triggerall=helper(21040),gethitvar(damage)=0
trigger1=numenemy=[1,2]
trigger1=enemy(0),movecontact!=0
trigger1=enemy(0),movereversed=0
trigger1=enemy(0),projcontact0=0
trigger2=numenemy=2
trigger2=enemy(1),movecontact!=0
trigger2=enemy(1),movereversed=0
trigger2=enemy(1),projcontact0=0
sysfvar(2)=ceil(sysfvar(2)-var(33)*(helper(21030),gethitvar(damage)+1000)/(abs(sysfvar(2)/10)+10000))
ignorehitpause=1

[state CSAS_footer]
type=varset
triggerall=!ishelper
trigger1=sysfvar(2)<var(37)
sysfvar(2)=var(37)
ignorehitpause=1

[state CSAS_enemies_increase]
type=varset
triggerall=!ishelper
trigger1=helper(21030),gethitvar(damage)>0
trigger1=numenemy=[1,2]
trigger1=enemy(0),projcontact0=1
trigger2=helper(21030),gethitvar(damage)>0
trigger2=numenemy=2
trigger2=enemy(1),projcontact0=1
trigger3=helper(21030),gethitvar(damage)>0
trigger3=numenemy=1
trigger3=enemy(0),movecontact=0
trigger3=movecontact=0
trigger4=helper(21030),gethitvar(damage)>0
trigger4=numenemy=2
trigger4=enemy(0),movecontact=0
trigger4=enemy(1),movecontact=0
trigger4=movecontact=0
trigger5=numhelper(21040)!=0
trigger5=helper(21040),gethitvar(damage)!=0
trigger5=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger6=numenemy=[1,2]
trigger6=enemy(0),numproj>20
trigger6=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger7=numenemy=2
trigger7=enemy(1),numproj>20
trigger7=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger8=numenemy=[1,2]
trigger8=enemy(0),numhelper>10
trigger8=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger9=numenemy=2
trigger9=enemy(1),numhelper>10
trigger9=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger10=abs(helper(21030),gethitvar(damage))>=(var(36)*110)
trigger10=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger10=var(36)<1000
sysfvar(2)=ceil(sysfvar(2)+var(32)*(helper(21030),gethitvar(damage)+1000)/(abs(sysfvar(2)/10)+ifelse((var(27)!=0)&&(palno=[3,6])&&(numexplod(8101082)=0),150000,50000)))
ignorehitpause=1

[state CSAS_state_increase]
type=varset
triggerall=!ishelper
triggerall=(var(27)=0)||((var(27)!=0)&&(palno!=[3,5])&&(numexplod(8101082)=0))||(numexplod(8101082)!=0)
trigger1=var(35)
trigger1=sysfvar(4)!=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
trigger2=sysfvar(2)>=5000
trigger2=sysfvar(4)!=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
trigger3=sysfvar(2)>=9000
trigger3=numprojID(21010)=0
trigger4=numexplod(21010)=0
sysfvar(2)=sysfvar(2)+var(32)/10
ignorehitpause=1

[state CSAS_header]
type=varset
triggerall=!ishelper
trigger1=numexplod(8101081)!=0
trigger1=1||var(14):=10000
trigger2=sysfvar(2)>var(14)
trigger3=var(37)<0
trigger4=var(37)>var(14)
trigger5=numexplod(8101082)!=0
sysfvar(2)=var(14)
ignorehitpause=1

[state CSAS_zero]
type=varset
triggerall=!ishelper
trigger1=(var(27)!=0)&&(palno=2)
trigger1=numexplod(8101082)=0
sysfvar(2)=0
ignorehitpause=1

[state nothitby_player]
type=nothitby
trigger1=!ishelper
trigger1=1
value=SCA,AA,AT,AP
time=99999
ignorehitpause=1

[state hitoverride_player]
type=hitoverride
triggerall=!ishelper
trigger1=1
attr=SCA,AA,AT,AP
stateno=5150
ignorehitpause=1

[state hitoverride_helper]
type=hitoverride
triggerall=ishelper
trigger1=!ishelper(21060)
attr=SCA,AA,AT,AP
stateno=const(size.shadowoffset)
ignorehitpause=1

[state power_recover]
type=poweradd
triggerall=!ishelper
trigger1=sysfvar(2)>0
trigger2=var(2)!=0
value=ifelse((sysfvar(2)>=1000)||(var(2)!=0)||(numexplod(8101082)!=0)||(numexplod(8101081)!=0),powermax,ifelse(sysfvar(2)>=100,3,1))
ignorehitpause=1

[state power_get]
type=poweradd
triggerall=!ishelper
trigger1=(anim=[200,203])||(anim=[300,303])||(anim=[636,640])
trigger1=movecontact=1
trigger2=helper(21030),gethitvar(damage)
value=ifelse(movehit,100,10)*((var(17)/100)+1)+(helper(21030),gethitvar(damage)/22)
ignorehitpause=1

[state dezolve_recover]
type=varset
triggerall=!ishelper
trigger1=sysfvar(2)>=1000
trigger1=var(21)<3
trigger2=sysfvar(2)>=500
trigger2=var(21)<2
trigger3=sysfvar(2)>0
trigger3=var(21)<1
v=21
value=ifelse(sysfvar(2)>=1000,3,ifelse(sysfvar(2)>=500,2,1))
ignorehitpause=1

[state dezolve_recover_2]
type=varset
triggerall=!ishelper
triggerall=(var(27)!=0)
trigger1=palno=12
trigger1=var(21)<3
trigger2=palno=11
trigger2=var(21)<2
trigger3=palno=[9,10]
trigger3=var(21)<1
v=21
value=ifelse(palno=12,3,ifelse(palno=11,2,1))
ignorehitpause=1

[state damage_add]
type=varadd
triggerall=!ishelper
triggerall=sysfvar(4)=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
triggerall=numhelper(21030)=1
triggerall=helper(21030),gethitvar(damage)>0
triggerall=numhelper(21040)!=0
triggerall=helper(21040),gethitvar(damage)=0
triggerall=(abs(helper(21030),gethitvar(damage))<(var(36)*110))||(var(36)>=1000)||((var(27)!=0)&&(palno=[2,7])&&(numexplod(8101082)=0))
trigger1=sysfvar(2)>=3000
trigger1=numenemy=1
trigger1=enemy(0),movecontact!=0
trigger1=enemy(0),projcontact0=0
trigger2=sysfvar(2)>=3000
trigger2=numenemy=2
trigger2=enemy(0),movecontact!=0
trigger2=enemy(0),projcontact0=0
trigger2=enemy(1),projcontact0=0
trigger3=sysfvar(2)>=3000
trigger3=numenemy=2
trigger3=enemy(1),movecontact!=0
trigger3=enemy(0),projcontact0=0
trigger3=enemy(1),projcontact0=0
trigger4=sysfvar(2)<3000
sysvar(4)=ceil(helper(21030),gethitvar(damage)/(abs(sysfvar(2)/10)+1))+1
ignorehitpause=1

[state damage_add_second]
type=varadd
triggerall=!ishelper
triggerall=sysfvar(4)=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
triggerall=numhelper(21030)=1
triggerall=helper(21030),gethitvar(damage)>0
triggerall=numhelper(21040)!=0
triggerall=helper(21040),gethitvar(damage)=0
triggerall=(abs(helper(21030),gethitvar(damage))<(var(36)*110))||(var(36)>=1000)||((var(27)!=0)&&(palno=[2,7])&&(numexplod(8101082)=0))
trigger1=sysfvar(2)>=3000
trigger1=numenemy=1
trigger1=enemy(0),movecontact!=0
trigger1=enemy(0),projcontact0=0
trigger2=sysfvar(2)>=3000
trigger2=numenemy=2
trigger2=enemy(0),movecontact!=0
trigger2=enemy(0),projcontact0=0
trigger2=enemy(1),projcontact0=0
trigger3=sysfvar(2)>=3000
trigger3=numenemy=2
trigger3=enemy(1),movecontact!=0
trigger3=enemy(0),projcontact0=0
trigger3=enemy(1),projcontact0=0
trigger4=sysfvar(2)<3000
sysvar(3)=-1*(ceil(helper(21030),gethitvar(damage)/(abs(sysfvar(2)/10)+1))+1)
ignorehitpause=1

[state damage_footer]
type=varset
triggerall=!ishelper
trigger1=sysvar(4)<0
trigger2=(110000-sysvar(4))!=sysvar(3)
trigger3=(var(27)!=0)&&(palno=[10,11])
trigger3=(sysfvar(2)>(3000+ifelse(palno=10,2000,0)))||(numexplod(8101082)!=0)
sysvar(4)=0
ignorehitpause=1

[state damage_footer_2]
type=varset
triggerall=!ishelper
trigger1=sysvar(3)>110000
trigger2=(110000-sysvar(4))!=sysvar(3)
trigger3=(var(27)!=0)&&(palno=[10,11])
trigger3=(sysfvar(2)>(3000+ifelse(palno=10,2000,0)))||(numexplod(8101082)!=0)
sysvar(3)=110000
ignorehitpause=1

[state damage_header]
type=varset
triggerall=!ishelper
trigger1=(sysvar(4)>110000)
sysvar(4)=110000
ignorehitpause=1

[state damage_header_2]
type=varset
triggerall=!ishelper
trigger1=(sysvar(3)<0)
sysvar(3)=0
ignorehitpause=1

[State life_set_zero]
type=lifeset
triggerall=!ishelper
triggerall=roundstate<=2
trigger1=alive!=0
trigger1=sysfvar(2)>=5000
trigger2=(sysvar(4)<110000)||(sysvar(3)>0)
trigger2=life=0
value=ifelse(((numenemy=1)&&(enemy(0),life=0))||(((numenemy=2)&&(enemy(0),life=0))&&((numenemy=2)&&(enemy(1),life=0))),1,ifelse((gametime%360)<180,0,1))
ignorehitpause=1

[State life_set]
type=lifeset
triggerall=!ishelper
trigger1=sysvar(4)>=(110000-life)
trigger2=roundstate>2
value=ifelse(roundstate>2,sysvar(3)+ceil(abs(sysfvar(2)*110)),110000-sysvar(4))
ignorehitpause=1

[state noKO]
type=assertspecial
triggerall=!ishelper
trigger1=((numenemy=1)&&(enemy(0),life!=0))||(((numenemy=2)&&(enemy(0),life!=0))&&((numenemy=2)&&(enemy(1),life!=0)))
trigger1=(sysvar(4)<110000)||(sysvar(3)>0)
trigger2=((numenemy=1)&&(enemy(0),life=0))||(((numenemy=2)&&(enemy(0),life=0))&&((numenemy=2)&&(enemy(1),life=0)))
trigger2=(sysvar(4)<110000)||(sysvar(3)>0)
trigger2=life=0
trigger3=(sysvar(4)<110000)||(sysvar(3)>0)
trigger3=alive=0
trigger4=sysfvar(4)!=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
trigger5=sysfvar(2)>=3000
trigger5=numprojID(21010)=0
trigger6=numexplod(21010)=0
trigger7=roundstate=3
trigger8=(numhelper(21030)=0)||(numhelper(21040)=0)
trigger9=((-1*sysvar(0)/364)-893)!=anim
flag=noKO
ignorehitpause=1

[state ignore_stop]
type=pause
;triggerall=roundstate<3
trigger1=!ishelper
trigger1=sysvar(4)!=110000
trigger2=!ishelper
trigger2=sysvar(3)!=0
trigger3=!ishelper
trigger3=alive!=0
trigger4=ishelper
time=2147483647
movetime=2147483647
unhittable=0
ignorehitpause=1

[state ignore_stop_2]
type=superpause
;triggerall=roundstate<3
trigger1=!ishelper
trigger1=sysvar(4)!=110000
trigger2=!ishelper
trigger2=sysvar(3)!=0
trigger3=!ishelper
trigger3=alive!=0
trigger4=ishelper
time=2147483647
movetime=2147483647
P2defmul=1
anim=-1
darken=0
unhittable=0
ignorehitpause=1

[state display]
type=displaytoclipboard
trigger1=!ishelper
text="HP:%d_%d_%d_%d_%d"
params=sysvar(3),var(23),numexplod,numexplod(8101082),numexplod(21030)


[state display]
type=displaytoclipboard
trigger1=ishelper(21040)
text="%d_%d_%d_%d"
params=numtarget,numtarget(21040),sysvar(2),sysvar(3)



;---------------------------------------------------------------------------

;---------------------------------------------------------------------------

[state explod_size_decrease_varset]
type=varset
triggerall=!ishelper
trigger1=(fvar(5)>=0)&&(fvar(5)<=2.0)
fvar(5)=fvar(5)+0.2
ignorehitpause=1

[state explod_size_footer]
type=varset
triggerall=!ishelper
trigger1=fvar(5)>2.0
fvar(5)=2.0
ignorehitpause=1

[state explod_resize]
type=modifyexplod
triggerall=!ishelper
trigger1=numexplod(15010)!=0
ID=15010
scale=2.5-fvar(5),2.5-fvar(5)
ignorehitpause=1

[state counter_explod]
type=explod
triggerall=!ishelper
trigger1=numtarget(15010+var(30))!=0
trigger1=movecontact=1
trigger1=1||fvar(5):=0
anim=15010
ID=15010
postype=Left
pos=ifelse(teamside=1,62,252),60
scale=2.5+fvar(5),2.5+fvar(5)
bindtime=-1
sprpriority=15010
supermovetime=99999
pausemovetime=99999
ontop=1
ignorehitpause=1

[state counter_announce]
type=playsnd
trigger1=numtarget(15010+var(30))!=0
trigger1=movecontact=1
value=s500,4
channel=0
ignorehitpause=1

[state explod_move_force]
type=modifyexplod
trigger1=roundstate>=2
ID=-1
supermovetime=9999999
pausemovetime=9999999
ignorehitpause=1

[state explod_ontop]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=-1
ontop=1
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4702
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4701
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4700
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4600
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4501
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=4500
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=11000
ontop=0
ignorehitpause=1

[state explod_ontop_not]
type=modifyexplod
trigger1=!ishelper
trigger1=sysfvar(2)>=3000
trigger2=ishelper
trigger2=root,sysfvar(2)>=3000
ID=11001
ontop=0
ignorehitpause=1

[state effect_explod_remove]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=3304
ID=4030
ignorehitpause=1

[state effect_explod_remove02]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=[2404,2405]
ID=6400
ignorehitpause=1

[state effect_explod_remove03]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=2403
ID=6369
ignorehitpause=1

[state effect_explod_remove04]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=2401
ID=6368
ignorehitpause=1

[state effect_explod_remove05]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=2402
ID=6367
ignorehitpause=1

[state effect_explod_remove06]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=2400
ID=6366
ignorehitpause=1

[state effect_explod_remove07]
type=removeexplod
triggerall=!ishelper
trigger1=anim!=[3500,3503]
ID=3510
ignorehitpause=1



;-----------------------------------------------------------------------------



[state gage_back]
type=explod
triggerall=!ishelper
trigger1=1
anim=12010
ID=12010
postype=Left
pos=ifelse(teamside=1,0,320),213
facing=ifelse(teamside=1,1,-1)
scale=0.5,0.5
bindtime=-1
removetime=1
sprpriority=9999999
supermovetime=9999999
pausemovetime=9999999
ontop=1
ownpal=1
ignorehitpause=1

[state gage_life]
type=explod
triggerall=!ishelper
trigger1=sysvar(3)!=0
anim=12999+ceil(sysvar(3)/687.5)
ID=13000
postype=Left
pos=ifelse(teamside=1,2,318),227
facing=ifelse(teamside=1,1,-1)
scale=0.5,0.5
bindtime=-1
removetime=1
sprpriority=99999999
supermovetime=9999999
pausemovetime=9999999
ontop=1
ownpal=1
ignorehitpause=1

[state gage_broste]
type=explod
triggerall=!ishelper
trigger1=var(17)!=0
anim=13199+ceil(var(17)/8.888)
ID=13200
postype=Left
pos=ifelse(teamside=1,2,318),215
facing=ifelse(teamside=1,1,-1)
scale=0.5,0.5
bindtime=-1
removetime=1
sprpriority=99999999
supermovetime=9999999
pausemovetime=9999999
ontop=1
ownpal=1
ignorehitpause=1

[state gage_desolve]
type=explod
triggerall=!ishelper
trigger1=var(21)!=0
anim=11999+var(21)
ID=12000
postype=Left
pos=ifelse(teamside=1,77,243),221
scale=0.5,0.5
bindtime=-1
removetime=1
sprpriority=99999999
supermovetime=9999999
pausemovetime=9999999
ontop=1
ownpal=1
ignorehitpause=1

[state CSAS_view1]
type=explod
triggerall=!ishelper
trigger1=sysfvar(2)!=0
trigger1=1||var(1):=ceil(sysfvar(2))%10
anim=22140+var(1)
ID=22140+var(1)
postype=Left
pos=ifelse(teamside=1,118,226),227
scale=0.5,0.5
bindtime=-1
sprpriority=22140
supermovetime=99999
pausemovetime=99999
ontop=1
ownpal=1
ignorehitpause=1

[state CSAS_view10]
type=explod
triggerall=!ishelper
trigger1=sysfvar(2)!=0
trigger1=1||var(1):=(ceil(sysfvar(2))%100)/10
anim=22140+var(1)
ID=22140+var(1)
postype=Left
pos=ifelse(teamside=1,110,218),227
scale=0.5,0.5
bindtime=-1
sprpriority=22140
supermovetime=99999
pausemovetime=99999
ontop=1
ownpal=1
ignorehitpause=1

[state CSAS_view100]
type=explod
triggerall=!ishelper
trigger1=sysfvar(2)!=0
trigger1=1||var(1):=(ceil(sysfvar(2))%1000)/100
anim=22140+var(1)
ID=22140+var(1)
postype=Left
pos=ifelse(teamside=1,102,210),227
scale=0.5,0.5
bindtime=-1
sprpriority=22140
supermovetime=99999
pausemovetime=99999
ontop=1
ownpal=1
ignorehitpause=1

[state CSAS_view1000]
type=explod
triggerall=!ishelper
trigger1=sysfvar(2)!=0
trigger1=1||var(1):=(ceil(sysfvar(2))%10000)/1000
anim=22140+var(1)
ID=22140+var(1)
postype=Left
pos=ifelse(teamside=1,94,202),227
scale=0.5,0.5
bindtime=-1
sprpriority=22140
supermovetime=99999
pausemovetime=99999
ontop=1
ownpal=1
ignorehitpause=1

[state CSAS_view10000]
type=explod
triggerall=!ishelper
trigger1=sysfvar(2)>=10000
anim=22141
ID=22141
postype=Left
pos=ifelse(teamside=1,86,194),227
scale=0.5,0.5
bindtime=-1
sprpriority=22140
supermovetime=99999
pausemovetime=99999
ontop=1
ownpal=1
ignorehitpause=1

;-----------------------------------------------------------------------------

;オーバーヒート中ヒートゲージ減少
[State -2]
type = Varadd
triggerall = !ishelper
triggerall = alive
triggerall = var(23) = 1
triggerall = stateno != 3550
trigger1 = gametime%1 = 0
var(22) = -1
ignorehitpause=1

;---------------------------------------------------------------------------
;勝利ポーズ時に歩くことが出来るバグについて
;
;WinMUGEN, MUGEN1.0ともに存在するバグへの対策です。
;相手をKOした時、吹き飛んだ相手をジャンプなどで飛び越えて着地した場合に
;方向キーを横に入れたままにすると歩き出してしまうので、
;CtrlSetを使って強制的に制御不能にさせます。

[State -2, 勝利バグ解消]
type = CtrlSet                 ;歩きバグ対策
trigger1 = RoundState = 4      ;勝利ポーズ時
trigger1 = Win && Ctrl = 1     ;動ける場合
value = 0                      ;制御不能に
ignorehitpause=1

;---------------------------------------------------------------------------
;---------------------------------------------------------------------------

;---------------------------------------------------------------------------

[state ctrl_set]
type=ctrlset
trigger1=!ishelper
trigger1=var(59)!=0
trigger2=ishelper
value=0
ignorehitpause=1

;---------------------------------------------------------------------------

[state helper_toumei]
type=assertspecial
triggerall=ishelper
;trigger1=!ishelper(21030)
trigger1=1
flag=invisible
flag2=noshadow
ignorehitpause=1

[state helper_offset]
type=bindtoroot
triggerall=ishelper
;trigger1=!ishelper(21030)
trigger1=1
facing=1
pos=0,0
ignorehitpause=1

[state remove_reversal_helper]
type=destroyself
triggerall=ishelper
trigger1=!ishelper(21030)
trigger1=!ishelper(21040)
trigger1=!ishelper(21050)
trigger1=!ishelper(21060)
trigger1=!ishelper(21070)
trigger1=!ishelper(21072)
trigger1=!ishelper(21100)
trigger1=!ishelper(21101)
trigger1=!ishelper(21102)
trigger1=!ishelper(21103)
trigger1=!ishelper(21104)
trigger1=!ishelper(21105)
trigger1=!ishelper(21106)
trigger1=!ishelper(21107)
trigger1=!ishelper(21108)
trigger1=root,movetype!=A
ignorehitpause=1

[state helper_selfstate]
type=selfstate
triggerall=ishelper
trigger1=1
trigger2=gethitvar(damage)
value=const(size.shadowoffset)
persistent=256
ignorehitpause=1

;---------------------------------------------------------------------------

[state killer_state_remember]
type=varset
triggerall=!ishelper
triggerall=hitpausetime=0
triggerall=1||var(11):=stateno
trigger1=sysfvar(4)!=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
trigger2=sysfvar(2)>=3000
trigger2=numprojID(21010)!=1
trigger3=numexplod(21010)!=1
trigger4=movereversed
sysvar(1)=var(11)
ignorehitpause=1

[state clsn1_remember]
type=null
triggerall=!ishelper
trigger1=numenemy=[1,2]
trigger1=enemy(0),movecontact!=0
trigger1=1||var(25):=enemy(0),anim
trigger2=numenemy=2
trigger2=enemy(1),movecontact!=0
trigger2=1||var(25):=enemy(1),anim
trigger3=helper(21040),sysvar(2)!=0
trigger3=1||var(25):=helper(21040),sysvar(2)
ignorehitpause=1

[state stateno_remember]
type=null
triggerall=!ishelper
trigger1=numenemy=[1,2]
trigger1=enemy(0),movecontact!=0
trigger1=1||var(24):=enemy(0),stateno
trigger2=numenemy=2
trigger2=enemy(1),movecontact!=0
trigger2=1||var(24):=enemy(1),stateno
trigger3=helper(21040),sysvar(3)!=0
trigger3=1||var(24):=helper(21040),sysvar(3)
ignorehitpause=1

[state intro_selfstate]
type=selfstate
triggerall=!ishelper
ytiggerall=roundstate<2
trigger1=stateno=5900
trigger1=1||var(47):=5900
value=931022810
persistent=256
ignorehitpause=1

[state win_selfstate]
type=selfstate
triggerall=!ishelper
triggerall=sysfvar(1)=(((gametime*const(data.life)/114514)*(gametime*0.93))/1.919810931)/gametime*id
triggerall=name="through_Lightning_Shuko"
trigger1=roundstate>3
trigger1=win
trigger1=alive
trigger1=sysvar(3)>0
trigger1=sysvar(4)<110000
trigger1=anim=0
trigger1=1||var(47):=180
value=931022810
persistent=256
ignorehitpause=1

[state timeover_selfstate]
type=selfstate
triggerall=!ishelper
triggerall=sysfvar(1)=(((gametime*const(data.life)/114514)*(gametime*0.93))/1.919810931)/gametime*id
triggerall=name="through_Lightning_Shuko"
trigger1=roundstate>3
trigger1=LoseTime||DrawGame
trigger1=anim=0
trigger1=1||var(47):=170
value=931022810
persistent=256
ignorehitpause=1

[state auto_reperburst]
type=selfstate
triggerall=!ishelper
triggerall=1||var(47):=0
trigger1=(sysvar(4)<110000)||(sysvar(3)>0)
trigger1=alive=0
trigger1=anim!=2901
trigger1=1||var(47):=2901
trigger2=roundstate>=2
trigger2=((-1*sysvar(0)/364)-893)!=anim
trigger2=(stateno!=52)&&(stateno!=47)&&(stateno!=[5100,5101])
trigger2=1||var(47):=2900
trigger3=sysfvar(4)!=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
trigger3=1||var(47):=0
trigger4=sysfvar(2)>=3000
trigger4=numprojID(21010)!=1
trigger4=1||var(47):=0
trigger5=numexplod(21010)!=1
trigger5=1||var(47):=0
trigger6=movetype=H
trigger6=1||var(47):=0
trigger7=movereversed
trigger7=1||var(47):=0
value=931022810
ctrl=1
persistent=256
ignorehitpause=1

[state gametime_reset]
type=varset
triggerall=!ishelper
trigger1=1
sysfvar(4)=0
ignorehitpause=1

[state hit_motion_selfstate]
type=selfstate
triggerall=!ishelper
triggerall=numhelper(21030)=1
triggerall=((var(27)=0)&&(numexplod(8101082)=0))||((var(27)!=0)&&(palno=[1,7])&&(numexplod(8101082)=0))
trigger1=sysfvar(2)<300
trigger1=helper(21030),gethitvar(damage)>0
trigger1=1||var(47):=155
value=931022810
persistent=256
ignorehitpause=1

[state anim_selfstate]
type=selfstate
triggerall=!ishelper
trigger1=(anim=[200,203])||(anim=[300,303])||(anim=[636,644])||(anim=[660,667])||(anim=800)||(anim=810)||(anim=900)||(anim=910)||(anim=[1000,1013])||(anim=[2900,2903])||(anim=[1200,1208])||(anim=[1500,1503])||(anim=0)
trigger2=(anim=[5000,5002])||(anim=[5005,5007])||(anim=[5010,5012])||(anim=[5015,5017])||(anim=[5020,5022])||(anim=[5025,5027])||(anim=5030)||(anim=5035)||(anim=5040)||(anim=5050)||(anim=5070)||(anim=5080)
trigger3=(anim=5110)||(anim=5120)||(anim=0)||(anim=[10,12])||(anim=[20,21])||(anim=[40,47])||(anim=[60,66])||(anim=[50,52])||(anim=[100,104])||(anim=[2300,2303])||(anim=[2400,2406])||(anim=[3300,3304])
trigger4=(anim=[2800,2801])||(anim=170)||(anim=[180,185])||(anim=[187,189])||(anim=[191,193])||(anim=[3500,3503])||(anim=[3900,3904])||(anim=[4100,4101])||(anim=5150)
trigger5=(stateno=[5100,5101])||(stateno=52)||(stateno=47)||(stateno=5900)
trigger5=1||var(47):=ifelse((stateno=[5100,5101]),5110,0)+ifelse((stateno=52),642,0)+ifelse((stateno=47),642,0)+ifelse((stateno=5900),5900,0)
trigger6=1||var(47):=ifelse(((-1*sysvar(0)/364)-893)!=anim,2900,anim)
value=931022810
persistent=256
ignorehitpause=1

;---------------------------------------------------------------------------

;---------------------------------------------------------------------------
[Statedef -3]
;---------------------------------------------------------------------------

[state gametime_save]
type=varset
triggerall=(!ishelper)||(ishelper(21030))
trigger1=1
sysfvar(4)=(((gametime*gametime/114.514)*gametime)/1919.810)/gametime
ignorehitpause=1

[state proj_counter]
type=projectile
triggerall=!ishelper
trigger1=sysfvar(2)>=3000
projanim=21010
projID=21010
projremovetime=0
ignorehitpause=1

[state explod_counter]
type=explod
triggerall=!ishelper
trigger1=numexplod(21010)=0
anim=21010
ID=21010
postype=p1
pos=0,0
bindtime=-1
removetime=0
ignorehitpause=1

;---------------------------------------------------------------------------




[State -3, 着地音]
type = PlaySnd
triggerall=!ishelper
triggerall=(animelem=1,=1)
trigger1 = stateno = 52
trigger2 = stateno = 106
value = 40, 0
ignorehitpause=1


[State -3, 砂埃]
type = Explod
triggerall=(animelem=1,=1)
trigger1 = stateno = 52
anim = 6000
sprpriority = 5
bindtime = 1
supermove = 1
ignorehitpause=1


;---------------------------------------------------------------------------



;---------------------------------------------------------------------------



[State -3, ダメージボイス]
type = PlaySnd
triggerall=(animelem=1,=1)
triggerall = Alive && GameTime % 3 = 0                  ;生きている時＆3Fに一回の確率で
trigger1 = stateno=5000 || stateno=5010 || stateno=5020 ;ダメージの瞬間
trigger2 = stateno = 5070 || stateno = 5080             ;ダメージの瞬間
value = 50,random/250                                   ;50,0～50,3までをランダムに決定
channel = 0 ;チャンネルを決定しています。同じチャンネルの音は重なりません。
ignorehitpause=1

[State -3, ガードボイス]
type = PlaySnd
triggerall=(animelem=1,=1)
triggerall = Alive && GameTime % 6 = 0               ;%は割ったあまりを求める
trigger1 = stateno=151 || stateno=153 || stateno=155 ;ガードのノックバック時
trigger2 = stateno = 702                             ;シールド成功時
value = 60,0;random/334                                ;60,0～60,2までをランダムに決定
channel = 0 ;例えば4チャンネルの音が新たに鳴った場合、現在の4chの音は消えます。
ignorehitpause=1

[State -3, 受身ボイス]
type = PlaySnd
triggerall=(animelem=1,=1)
triggerall = Alive && GameTime % 3 = 0      ;GameTimeを3で割ったあまりが0の時
trigger1 = stateno = 5200 || stateno = 5210 ;受身直後
value = 70,random/334
channel = 0 ;そのおかげで、各ボイスが同時に発せられることがなくなります。
ignorehitpause=1

[State -3, 起き上がりボイス]
type = PlaySnd
triggerall=(animelem=1,=1)
triggerall = Alive && GameTime % 3 = 0
trigger1 = stateno = 5120              ;起き上がり時
value = 80,random/334
channel = 0 ;キャラボイスは0chを推奨
ignorehitpause=1


;--------------------------------------------------------------------------





